Carga Masiva de anexos en SAP

El código de la anterior entrada esta limitado a un solo archivo que debe ser elegido por el usuario pero ¿ Y si necesitamos cargar 1000 pdf  o 10000...o 100000!!? .

Si utilizamos la clase CL_GOS_DOCUMENT_SERVICE anexaríamos de uno en uno....demasiado tiempo y el programa podria llegar a ralenizar todo el sistema.

Lo primero de todo, es especificar  una relación entre los archivos  y objetos de negocio en sap (solicitudes de compra, pedidos de compra, pedidos de venta documentos contables ) .  Gracias a esta relación podremos determinar a que objeto de negocio anexar cada archivo del directorio. Podemos determinar cualquier relación como por ejemplo que el nombre del archivo coincidirá con el nº de factura que referencia el documento contable en SAP.

Por ejemplo, la Factura 0000157910 es el archivo  0000157910.PDF y el archivo 0000157910.PDF tiene que adjuntarse al documento contable que tenga la factura  0000157910 como documento de referencia (campo BKPF-XBLNR).

Como caso de prueba, tenemos un directorio "fuente" con 6 facturas en PDF,

Facturas en PDF y los doc. contables a los que deben ser adjuntadas

El nombre del archivo es el nº de factura y coincide con el campo BKPF-XBLNR del doc. contable.

El programa seguirá la siguiente lógica:

1. Lee los archivos del directorio "fuente"
2. Busca los doc. contables con BKPF-XBLNR igual al nombre del archivo
3. Si existe, anexa el archivo al doc. contable y mueve el archivo al directorio "procesados".
4. Si no existe, deja el archivo en el directorio fuente

Podeis encontrar el código del programa en el repositorio git del blog:

• Programa ZZ_ATTA_MULTIPLES_PDF

Para organizar mejor el código he dividido el programa en 3 archivos:

• ZZ_ATTA_MULTIPLES_PDF: programa pincipal.
• ZZ_ATTA_MULTIPLES_PDF_TOP: variables globales.
• ZZ_ATTA_MULTIPLES_PDF_F01: Subrutinas.

Notas OSS de interes:
927407 - Determining the content of GOS and SAPoffice documents
904711 - SAPoffice: Where are documents physically stored?
916512 - SAPoffice: Directory for upload/download/display
448074 - Calling generic object services from the dialog

Entradas Anteriores:

I ain't afraid of no GOS

Cambiar la categoría de archivo para GOS
RSIRPIRL: recolocando los contenidos de SOFFCONT1 
Crear, Visualizar y Borrar anexos con CL_GOS_DOCUMENT_SERVICE

Crear, Visualizar y Borrar anexos con CL_GOS_DOCUMENT_SERVICE

Seguimos con los anexos. Esta vez vamos a hablar de la clase CL_GOS_DOCUMENT_SERVICE.

En la transacción SE24 podemos visualizar sus métodos y atributos:

CL_GOS_DOCUMENT_SERVICE

Esta clase tiene muchos métodos para crear, modificar, borrar y visualizar documentos anexos a un objeto de negocio.

Para los ejemplos con esta clase, seguiremos utilizando el anexo de archivos a documentos contables en SAP pero recordemos que es posible anexar archivos a un gran numero de objetos de negocio en SAP ( materiales, facuras, pedidos de compra, etc... ).


CREAR ANEXO

Seleccionado el documento contable, se abre una ventana del explorador de archivos, seleccionamos el archivo a anexar, y en la FB03 comprobamos que se ha anexado correctamente

Crear Anexo

VISUALIZAR  ANEXOS

Primero recuperamos los anexos del documento contable en la tabla SRGBTBREL, pero aquí solo esta el enlace interno al anexo, para recuperar el  nombre del anexo utilizar  la bapi SO_OBJECT_GET_CONTENT

Visualizar Anexo

BORRAR ANEXOS

Primero recuperamos los anexos del documento contable en la tabla SRGBTBREL, pero aquí solo esta el enlace interno al anexo, para recuperar el  nombre del anexo utilizar  la bapi SO_OBJECT_GET_CONTENT selecionamos el anexo y comprobamos que se ha borrado en al FB03

Borra Anexo

CODIGO ABAP

Y llegamos  lo importante, aqui esta el codigo ABAP que permite crear, visualizar y borrar anexos.

Teneis también el código ABAP disponible en el repositorio github del blog

• Código ABAP de ZZ_PRUEBAS_ANEXOS_GOS

REPORT ZZ_PRUEBA_ANEXOS_GOS.

*&---------------------------------------------------------------------*
*& TYPE-POOLS
*&---------------------------------------------------------------------*
TYPE-POOLS: slis. 
*&---------------------------------------------------------------------*
*& Tablas
*&---------------------------------------------------------------------*
TABLES: BSEG.

*&---------------------------------------------------------------------*
*& Variables Glovales
*&---------------------------------------------------------------------*
DATA: obj_gos        TYPE REF TO cl_gos_document_service.
DATA: wa_borident TYPE                borident.
DATA: wa_objkey   TYPE                borident-objkey.

*&---------------------------------------------------------------------*
*& Parámetros de Selección
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK BLOCK01 WITH FRAME TITLE TEXT-S01.
PARAMETERS: P_BUKRS TYPE BUKRS OBLIGATORY,
                           P_BELNR TYPE BELNR_D OBLIGATORY,
                           P_GJAHR TYPE GJAHR OBLIGATORY.
SELECTION-SCREEN END OF BLOCK BLOCK01.

SELECTION-SCREEN BEGIN OF BLOCK BLOCK02 WITH FRAME TITLE TEXT-S01.
PARAMETERS: P_crear  type c RADIOBUTTON GROUP GR1,
                           P_visua  type c RADIOBUTTON GROUP GR1,
                           P_borra type c RADIOBUTTON GROUP GR1.
SELECTION-SCREEN END OF BLOCK BLOCK02.

*&---------------------------------------------------------------------*
*& Validaciones de Pantalla
*&---------------------------------------------------------------------*
AT SELECTION-SCREEN.

*&---------------------------------------------------------------------*
*& INITIALIZATION
*&---------------------------------------------------------------------*
INITIALIZATION.

*&---------------------------------------------------------------------*
*& START-OF-SELECTION
*&---------------------------------------------------------------------*
START-OF-SELECTION.

SELECT SINGLE *
      FROM BSEG
      WHERE BUKRS EQ P_BUKRS
           AND BELNR EQ P_BELNR
           AND GJAHR EQ P_GJAHR.

IF ( SY-SUBRC <> 0 ).
     MESSAGE 'No existe el documento' TYPE 'S' DISPLAY LIKE 'E'. 
ELSE.

CREATE OBJECT obj_gos.

CONCATENATE P_BUKRS P_BELNR P_GJAHR INTO wa_borident-objkey.
wa_borident-objtype = 'BKPF'.

IF P_crear IS NOT INITIAL.

CALL METHOD obj_gos->create_attachment
     EXPORTING        
        is_object = wa_borident
     IMPORTING
        ep_attachment = wa_borident-objkey.

COMMIT WORK.

ELSEIF p_visua IS NOT INITIAL.

    PERFORM SELECT_ATTA USING  wa_borident CHANGING  wa_objkey.


    IF  ( wa_objkey IS NOT INITIAL ).
       CALL METHOD obj_gos->display_attachment
               EXPORTING
                    ip_attachment = wa_objkey.
    ENDIF.

  ELSEIF P_Borra IS NOT INITIAL.

    PERFORM SELECT_ATTA USING wa_borident CHANGING wa_objkey.

    IF  ( wa_objkey IS NOT INITIAL ).
        CALL METHOD obj_gos->delete_attachment
               EXPORTING
                   ip_attachment = wa_objkey.

        COMMIT WORK. 
   ENDIF.

  ENDIF.

ENDIF. 

*&---------------------------------------------------------------------*
*& Form SELECT_ATTA
*&---------------------------------------------------------------------*
* Muestra un Popu para que el cliente seleccione el adjunto
*----------------------------------------------------------------------*
FORM  SELECT_ATTA USING    pi_borident TYPE borident
                  CHANGING po_objkey   TYPE borident-objkey.

    TYPES: BEGIN OF type_anexos,
      box(1)   TYPE C,
      instid_b TYPE srgbtbrel-instid_b,
      name(15) TYPE C,
    END OF type_anexos.

    DATA: tl_anexos TYPE STANDARD TABLE OF type_anexos, 
          tl_head TYPE STANDARD TABLE OF SOLI,
          tl_cond TYPE STANDARD TABLE OF SOLI,
          i_fieldcat TYPE  SLIS_T_FIELDCAT_ALV,

          l_program  TYPE sY-REPID.

    DATA: Wl_SOODK TYPE SOODK,
          w_fieldcat TYPE slis_fieldcat_alv.

    FIELD-SYMBOLS: <fanexos> TYPE type_anexos,
                   <fsoli>   TYPE SOLI.

    CLEAR: po_objkey.
    REFRESH: TL_anexos.

    SELECT instid_b INTO CORRESPONDING FIELDS OF TABLE TL_anexos
          FROM srgbtbrel
            where   instid_a = pi_borident-objkey
              and   typeid_a = pi_borident-objtype
              and   reltype  = 'ATTA'.

    LOOP AT TL_anexos ASSIGNING <fanexos>.

        CLEAR Wl_SOODK.

        Wl_SOODK-OBJTP = <fanexos>-instid_b+17(3).
        Wl_SOODK-OBJYR = <fanexos>-instid_b+20(2).
        Wl_SOODK-OBJNO = <fanexos>-instid_b+22.

        CALL FUNCTION 'SO_OBJECT_GET_CONTENT'
          EXPORTING
            object_id              = Wl_SOODK
          tables
            OBJHEAD                = tl_head
            objcont                = tl_cond
          EXCEPTIONS
           ARCHIVE_ERROR          = 1
           OBJECT_NOT_EXIST       = 2
           OTHERS                 = 3
                  .
        IF sy-subrc EQ 0.

          READ TABLE tl_head INDEX 1 ASSIGNING <FSOLI>.
          IF ( SY-SUBRC EQ 0 ).
            <fanexos>-NAME = <FSOLI>-LINE+13.
          ENDIF.

        ENDIF.

    ENDLOOP.

    l_program = sy-repid.

    w_fieldcat-fieldname = 'NAME'.
    w_fieldcat-tabname   = 'TL_ANEXOS'.
    w_fieldcat-seltext_m = 'Anexo'.
    APPEND w_fieldcat TO i_fieldcat.

    call function 'REUSE_ALV_POPUP_TO_SELECT'
      exporting
        i_title     = TEXT-T01
        i_tabname   = 'TL_ANEXOS'
        i_selection = 'X'
        i_zebra = 'X'
        i_checkbox_fieldname = 'BOX'
        it_fieldcat          = i_fieldcat
        i_callback_program   = l_program
      tables
        t_outtab = TL_ANEXOS
      exceptions
        program_error = 1
        others = 2.

    IF ( Sy-SUBRC EQ 0 ).
      READ TABLE TL_ANEXOS WITH KEY BOX = 'X' ASSIGNING <fanexos>.
      IF ( SY-SUBRC EQ 0 ).
        po_objkey = <fanexos>-instid_b.
      ENDIF.
    ENDIF.

endform.                    " SELECT_ATTA 

Entradas Siguientes:
Carga masiva de anexos en SAP

Entradas Anteriores:

I ain't afraid of no GOS

Cambiar la categoría de archivo para GOS
RSIRPIRL: recolocando los contenidos de SOFFCONT1  

RSIRPIRL: recolocando los contenidos de SOFFCONT1

En la transacción DB12 se puede comprobar el tamaño de la tabla SOFFCONT1:

• Transacción DB12 -> Space -> Single Table Analysis -> SOFFCONT1

DB12 tamaño de la tabla SOFFCONT1

Si el tamaño de la tabla es muy grande, con el programa estándar RSIRPIRL es posible mover el contenido de una categoría de archivo a otra es decir, podemos liberar espacio en la tabla SOFFCONT1 y traspasar el contenido de los archivos y documentos anexados a un repositorio externo. 

Antes de ejecutar el programa, recomiendo aplicar los cambios de la siguiente nota de SAP:

• Note 1536325 - Enhancement for report RSIRPIRL

Esta nota amplia la pantalla de selección del programa para poder seleccionar por la fecha de creación. Esto es muy útil para poder realizar pruebas o mover solamente algunos anexos.

Una vez aplicada la nota, podemos ejecutar el programa. Por ejemplo, vamos a traspasar desde la categoría de archivo SOFFDB ( base de datos , tabla SOFFCONT1 ) a la nueva categoría SOFFHTTP todos los anexos creados en el mes de septiembre de 2012:

El enlace entre Clase y Categoría puede verse en la Transacción SKPR08.

Las categorías de archivo están en la transacción OACT.

Notas OSS de interés:

Note 1536325 - Enhancement for report RSIRPIRL

Entradas Anteriores:

I ain't afraid of no GOS

Cambiar la categoría de archivo para GOS

Entradas siguientes:
Crear, Visualizar y Borrar anexos con CL_GOS_DOCUMENT_SERVICE 
Carga masiva de anexos en SAP

Cambiar la categoría de archivo para GOS

Como hemos comentado en la entrada anterior, el contenido de los archivos anexados se guardan en la tabla SOFFCONT1 de la base de datos. Si los archivos anexados son muy grandes o vamos a anexar un gran numero de archivos, esta tabla puede llegar a ocupar una gran cantidad de espacio y ralentizar el sistema. Imaginar por ejemplo una empresa que anexa cada mes 100 facturas a sus respectivos documentos contables cada mes; con el paso del tiempo, la tabla SOFFCONT1 puede llegar a contener miles de archivos anexados.

Podemos comprobar el tamaño de la tabla SOFFCONT1:

   Transacción DB12 -> Space -> Single Table Analysis -> SOFFCONT1

DB12 - tamaño de la tabla SOFFCONT1

SAP recomienda que si el volumen de archivos va ha ser muy alto,  se configure el sistema para almacenar los archivos en un contenedor de archivos  o content server en ingles. Existen varios sistemas de gestión de contenido que ofrecen contenedor de archivos co  con SAP, aquí solamente comentare alguno de ellos:

• SAP Content Server es una aplicación stand-alone para el almacenamiento de archivos y documentos que puedan ser usados por las aplicaciones SAP. Si nuestro cliente tiene instalado el SAP Content Server podemos utilizarlo para almacenar en él los archivos anexados. Tiene ciertas limitaciones como que no podemos almacenar y anexar automáticamente un documento desde un escaner. 
• OpenText Content Suite Platform es la solución de OpenText para la gestión documental o Enterprise Content Management (ECM). Es mucho mas potente que el SAP Content Server y recomendable si estamos pensado más a largo. Permite gestionar y controlar todo el proceso desde la creación o captura del documento hasta su archivado.

A continuación, explico el proceso para crear un repositorio externo y la categoría de archivo .

1.- Crear el repositorio de contenido y la conexión al content server. Transacción OAC0.

Este repositorio debe contener los datos de conexión al content servet como la IP. puerto, etc...

2.- Crear una nueva categoría de archivo SOFFHTTP  y enlazar con el repositorio creado. Transacción OACT

Si ya existe SOFFHTTP o no queréis utilizar esta categoría de archivo, podéis crear una nueva, por ejemplo ZPDF_IMAGE.

3.- Asignar la categoría de archivo a la categoría para clases de documentos físicos.
Transacción SKPR08

Asignamos la nueva categoría de archivo SOFFHTTP a la clase SOFFPHIO.

Si no aparece la clase SOFFPHIO en la SKPR08, hay que aplicar la nota de SAP:

• 668271 - The entry SOFFPHIO is not displayed in TR SKPR08

Desde la transacción SE16 abrimos la tabla SDOKPHCL , buscamos el registro PH CLASS=SOFFPHIO. Modificar el registro para quede como en la imagen:

Si ahora, por ejemplo, anexais un pdf a un documento contable. el contenido del archivo ya no se almacenara en la tabla SOFFCONT1. Podréis seguir visualizando el pdf pero ahora esta almacenado en el repositorio Z1. 

Si aun no os creeis que ahora esta almacenado el archivo en el repositorio Z1, podéis cambiar  la IP al repositorio Z1.  Si lo haceis, comprobareis que ya no podremos acceder al anexo, porque nuestro repositorio ya no apunta al content server que lo guarda; esto es la prueba que el archivo se ha almacenado en el  content server y no a la base de datos de SAP.

Referencias:

Create Attachment issue in storing the document

SAP Content server

Notas OSS de interes:

668271 - The entry SOFFPHIO is not displayed in TR SKPR08

Entradas anteriores:

I ain't afraid of no GOS

Entradas siguientes:

RSIRPIRL: recolocando los contenidos de SOFFCONT1

Crear, Visualizar y Borrar anexos con CL_GOS_DOCUMENT_SERVICE 

Carga masiva de anexos en SAP

I ain't afraid of no GOS

G.O.S ( Generic Object Services )  nos ofrecen una serie de servicios  con los que poder anexar  archivos (pdf, doc, xml, jpg, bmp,.. ),  URL y notas personales a un objeto de negocio de Sap ( Facturas, Doc. contables, pedidos de venta, doc. del material...). Un ejemplo real seria, cuando a un pedido de venta, le adjuntamos una hoja donde esta detalladas las características del producto y lo agarramos con un clip.

Es mucho mas recomendable crear URLs que anexar un archivo, Una URL es simplemente un link a un archivo existente localmente en el pc o en un servidor, mientras que anexar un archivo implica subir ese archivo a la base de datos de SAP lo que puede generar un problema de espacio y si anexamos un gran numero de archivos puede sobrecargar la base de datos, tampoco existe la opción de actualizar un archivo anexado, tendríamos que borrar el archivo anexado actual y subir el nuevo archivo.

En muchas transacciones de Sap esta opción esta disponible en la esquina superior izquierda:

Botón Anexos, en la esquina superior izquierda

Imaginemos que tienes una factura en PDF y quieres adjuntarla a su documento contable.

Accedemos al doc. contable en la FB03 y desplegamos el menú, seleccionamos "crear anexo".

A continuación, aparecerá el explorador de archivos del sistema, seleccionamos el archivo a exportar

Para poder visualizar, desplegamos el menú otra vez y seleccionamos "lista de anexos"

Doble click sobre el documento ara abrirlo.

Bien, ahora os estaréis preguntado " ¿Donde ha guardado SAP el documento anexado?".

Los archivos anexados, URL y notas se tratan como documentos del Sapoffice y su contenido, hasta la versión 4.6B, se guardaba en la tabla SOC3. Pero a partir de la versión 4.6B el almacenamiento de estos documentos pasa a ser responsabilidad del Knowledge Provider (Kpro) que permite un almacenamiento externo evitando la sobrecarga de la base de datos de SAP.

A partir de la versión 4.6B lsa notas personales y URL siguen almacenándose en la tabla SOC3, pero los archivos anexados pasan a almacenarse en la tabla SOFFCONT1, para gestionar estos anexos, SAP crea un vinculo entre el objeto de negocio y el archivo indexado, estos vínculos se almacenan en la tabla SRGBTBREL, enlaces en el entorno GOS.

En el ejemplo anterior, hemos anexado el pfd al doc. contable 131 de la sociedad 1000 del ejercicio 2011, si buscamos en la tabla  SRGBTBREL  encontramos:

Vamos a seguir tirando del hilo, nos quedamos con la cadena 'EXT37000000000105' del campo INSTID_B. Nos vamos a la SE37 y ejecutamos la bapi SO_OBJECT_GET_CONTENT , rellenamos el parámetro de entrada OBJECT_ID con los anteriores datos.

En la tabla se salida OBJCONT, encontramos el identificador lógico del objeto, necesitamos el identificador físico, la relación entre ambos esta almacenada en la tabla SOFFPHIO, instancias de objetos de información físicos.

Con este identificador físico , vamos a la SOFFCONT1 donde se almacena el archivo como cluster en formato hexadecimal. como veis un solo archivo anexado puede ocupar MUCHO espacio.

Para saber como esta parametrizado tu sistema SAP, nos vamos a la tabla SDOKPHCL, clases de objetos de información físicos. Buscamos la clase SOFFPHIO.

Si STOR_CAT = SOFFDB, significa que los anexos se suben a la base de datos de SAP en la tabla  SOFFCONT1.

transacción OACT: Categorías de archivo

Notas OSS de interes:
530792 - Storing documents in the generic object services
904711 - SAPoficce: Where are documents physically stored?

Entradas siguientes:
Cambiar la categoría de archivo para GOS
RSIRPIRL: recolocando los contenidos de SOFFCONT1
Crear, Visualizar y Borrar anexos con CL_GOS_DOCUMENT_SERVICE

Carga masiva de anexos en SAP