Código de Retorno: GUIXT: Añadir y Modificar campos de texto, pulsadores y radiobuttons

En esta nueva entrada sobre GuiXT añadiremos o modificaremos elementos de la pantalla como los pulsadores, radiobuttons, campos de texto y textos de ayuda.

Ejemplo: Añadir 3 botones en la barra de herramientas de la transacción VA01 (Crear pedido)

El objetivo es que estos pulsadores, permitan navegar desde la transacción VA01 a las transacciones:

VA15: Lista de consultas
VA25: Lista de ofertas
VA05: Lista de pedidos

Desde la transacción VA01, clic en el pulsador "SCRIPT" en la ventana de GuiXT.

pushbutton (toolbar) "@3B\QLista de consultas@Consultas"   "/OVA15" 
pushbutton (toolbar) "@3B\QLista de ofertas@Ofertas"       "/OVA25" 
pushbutton (toolbar) "@3B\QLista de pedidos@Pedidos"       "/OVA05"

Grabamos el archivo y volvemos a entrar en la transacción VA01

Nuevos pulsadores en la barra de herramientas de la transacción VA01

No solo podemos añadir los pulsadores en la barra de herramientas, también en cualquier posición de la pantalla.

box (11,0) (15,49)"Listas"
pushbutton (12,1) "@3b\QLista de consultas@Consultas" "/OVA15"  Size=(3,14)
pushbutton (12,17) "@3B\QLista de ofertas@Ofertas"    "/OVA25"  Size=(3,14)
pushbutton (12,34) "@3B\QLista de pedidos@Pedidos"    "/OVA05"  Size=(3,14)

Al grabar y volver a entrar en la transacción VA01.

Nuevos pulsadores en la transacción VA01

Añadir un pulsador a la barra de herramientas de la pantalla .

Pushbutton (Toolbar) "Pushbutton text" "FCode"

Añadir un pulsador en las coordenadas especificadas de la pantalla.

Pushbutton (row,column) "Pushbutton text" "FCode" Process="..."

La instrucción Pushbutton, añade un pulsador en las coordenadas especificadas (row,column) con el texto "Pushbutton text" que al presionar ejecutara el código interno "FCode". El código interno puede ser un código del menú como SCMP, una transacción “/NVA3” , “/NMM01” … ó una combinación de teclas como F1, F2, … Shilt+F1, Shilt+...

El parámetro Process="..." se relaciona con un fichero InputScript.

Se puede omitir el parámetro "FCode", si solo es necesario un “Intro” para continuar con la transacción

Ejemplo: Simplificar la pantalla de selección de la transacción MD01

Con GuiXT también es posible sustituir los campos de entrada de datos por selecciones de radiobuttos, asignar valores por defecto o reducir la longitud de los campos de entrada en la pantalla de selección.

El objetivo de estas modificaciones puede ser:

Simplificar al usuario la selección de datos al usuario
Reducir el tiempo el tiempo de aprendizaje para el usuario
Reducir el tiempo que necesita el usuario para ejecutar la transacción

Como ejemplo, vamos a simplificar la pantalla de selección de la transacción MD01

Algunos campos de entrada podrían ser sustituidos por radiobuttons de selección con los posibles valores de entrada, simplipicaría al usuario la ejecución, solo tendría que seleccionar uno de los valores que se muestran.

Si en la empresa, solo existen 3 centros; simplificamos la pantalla de selección eliminado este campo de la pantalla y sustituyéndolo por 3 radiobuttons con valores existentes.

También, en el area de “Parámetros de control planificación” liberaremos al usuario de aprender y recordar los valores de cada campo de entrada, sustituiremos los campos de entrada por grupos de radiobuttons y marcaremos valores por defecto para los mismos.

El código del GuiXT script seria:

// ----------------------------------------------------
// Centro 
// ---------------------------------------------------- 

offset (0,1) 
box (0,0) (5,60)  "Ejecutar MRP para el Centro "

box (6,0) (21,60) "Parámetros para la ejecución del MRP"

radiobutton (2,2) "1000 Barcelona" F[Centro] "1000" 
radiobutton (3,2) "2000 Madrid"    F[Centro] "2000" 
radiobutton (4,2) "9000 Zaragoza"  F[Centro] "9000" 
Default F[Centro] "1000" 

// ---------------------------------------------------- 
// Programación de la ejecución
// ---------------------------------------------------- 

offset (8,3) 
box (0,0) (3,45)  "Programacion" 
radiobutton (1,1) "Datos Basicos"            F[Programación] "1" 
radiobutton (2,1) "Planif. de capacidades"   F[Programación] "2" 

// ---------------------------------------------------- 
// Schedule lines 
// --------------------------------------------------- 

offset (12,3) 
box (0,0) (3,45)  "Repartos plan de entrega" 
radiobutton (1,1) "Si" F[Repartos plan de entregas] "3" 
radiobutton (2,1) "No" F[Repartos plan de entregas] "1" 

// ---------------------------------------------------- 
// Modo Planificación
// ---------------------------------------------------- 

offset (16,3) 
box (0,0) (4,45)  "Modo planificación" 
radiobutton (1,1) "Adaptar datos de planificación" F[Modo planificación] "1" 
radiobutton (2,1) "Borrar y crear los datos" F[Modo planificación] "3" 
radiobutton (3,1) "Explosión nva.lst.materiales y hoja ruta" F[Modo planificación] "2" 

// ---------------------------------------------------- 
// Pulsador "Ejecutar selección" 
// ---------------------------------------------------- 

offset (22,1) 
pushbutton (0,0) "Ejecutar selección" "/0" size=3 

// ---------------------------------------------------- 
// Valores por defecto 
// ---------------------------------------------------- 

set C[Visualizar lista materias] "X" 
set F[Clave de tratamiento] "NETCH" 
set F[Crear lista MRP] "1" 
set F[Modo planificación] "1" 
set F[Alcance planific.] "Todo" 

// ---------------------------------------------------- 
// Eliminar los campos que son necesarios 
// ---------------------------------------------------- 

del F[Centro] "-triple" 
del F[Alcance planific.] "-triple" 
del G[Parámetros de control planificación] 
del G[Parámetros de control proceso] 
del G[Exit usuario: selección materiales para planificación]

Grabamos el archivo y volvemos a entrar en la transacción MD01.